高斯模糊

Shader "URP/GaussianBlur"
{
    Properties
    {
        [MainTexture]_MainTex ("Texture", 2D) = "white" {}
        [MainColor]_Color ("Color",Color) = (1,1,1,1)
        [IntRange]_BlurRadius ("BlurRadius", Range(1,15)) = 5
    }
    SubShader
    {
        Tags
        {
            "RenderType"="Transparent"
            "RenderPipeline"="UniversalPipeline"
            "IgnoreProjector"="true"
            "Queue"="Transparent" // Transparent AlphaTest Geometry Background
        }
        LOD 100
        Blend SrcAlpha OneMinusSrcAlpha

        HLSLINCLUDE

        
        #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
        

        TEXTURE2D_X(_MainTex);
        SAMPLER(sampler_MainTex);

        CBUFFER_START(UnityPerMaterial)
        half4 _Color;
        half4 _MainTex_ST;
        half4 _MainTex_TexelSize;
        int _BlurRadius;
        CBUFFER_END

        
        struct Attributes
        {
            half4 position : POSITION;
            half2 uv : TEXCOORD0;
        };


        struct Varyings
        {
            half4 position_sv : SV_POSITION;
            half2 uv : TEXCOORD0;
        	half4 uv01 : TEXCOORD1;
        	half4 uv23 : TEXCOORD2;
        };

		/***  方式1 ***/
        //这一步其实可以用计算出来的常量来替代，不需要在循环中每一步计算
		half GetGaussWeight(half x, half y, half sigma)
		{
			half sigma2 = pow(sigma, 2.0f);
			half left = 1 / (2 * sigma2 * 3.1415926f);
			half right = exp(-(x*x+y*y)/(2*sigma2));
			return left * right;
		}

        half4 GaussBlur(float2 uv)
		{
			//因为高斯函数中3σ以外的点的权重已经很小了，因此σ取半径r/3的值
			half sigma = _BlurRadius / 3.0h;
			half4 col = half4(0, 0, 0, 0);
			for (int x = - _BlurRadius; x <= _BlurRadius; ++x)
			{
				for (int y = - _BlurRadius; y <= _BlurRadius; ++y)
				{
					//获取周围像素的颜色
					//因为uv是0-1的一个值，而像素坐标是整形，我们要取材质对应位置上的颜色，需要将整形的像素坐标
					//转为uv上的坐标值
					half4 color = SAMPLE_TEXTURE2D_X(_MainTex,sampler_MainTex,uv + half2(x * _MainTex_TexelSize.x, y * _MainTex_TexelSize.y));
					//获取此像素的权重
					half weight = GetGaussWeight(x,y, sigma);
					//计算此点的最终颜色
					col += color * weight;
					
				}
			}
			return col;
		}
        

        /*** 方式2 ***/
        //【5】准备高斯模糊权重矩阵参数7x4的矩阵 ||  Gauss Weight
		static const half4 GaussWeight[7] =
		{
			half4(0.0205,0.0205,0.0205,0),
			half4(0.0855,0.0855,0.0855,0),
			half4(0.232,0.232,0.232,0),
			half4(0.324,0.324,0.324,1),
			half4(0.232,0.232,0.232,0),
			half4(0.0855,0.0855,0.0855,0),
			half4(0.0205,0.0205,0.0205,0)
		};

        // 水平一次 垂直一次
        half4 GaussBlur2(half2 uv,half2 offset)
		{
			//【11.2】获取偏移量
			half2 OffsetWidth = _MainTex_TexelSize.xy * offset;
			//从中心点偏移3个间隔，从最左或最上开始加权累加
			half2 uv_withOffset = uv - OffsetWidth * 3.0;
	 
			//【11.3】循环获取加权后的颜色值
			half4 color = 0;
			for (int j = 0; j < 7; j++)
			{
				//偏移后的像素纹理值
				half4 texCol = SAMPLE_TEXTURE2D_X(_MainTex, sampler_MainTex,uv_withOffset);
				//待输出颜色值+=偏移后的像素纹理值 x 高斯权重
				color += texCol * GaussWeight[j];
				//移到下一个像素处，准备下一次循环加权
				uv_withOffset += OffsetWidth;
			}
	 
			//【11.4】返回最终的颜色值
			return color;
		}

        
        /*** 方式3 ***/
        half GetGaussWeight3(half x,half sigma)
		{
			half sigma2 = pow(sigma, 2.0h);
			half left = 1 / (sigma * sqrt(2*PI));
			half right = exp(-pow(x,2.0h)/2*sigma2);
			return left * right;
		}

        half4 GaussBlur3(Varyings IN)
        {
        	half4 color = 0;
        	half sigma = 1;
	        half w0 = GetGaussWeight3(0,sigma);
            half w1 = GetGaussWeight3(1,sigma);
            half w2 = GetGaussWeight3(2,sigma);
            half sum = w0+w1*2+w2*2;
            color += w0/sum * SAMPLE_TEXTURE2D_X(_MainTex, sampler_MainTex,IN.uv);  
            color += w1/sum * SAMPLE_TEXTURE2D_X(_MainTex, sampler_MainTex,IN.uv01.xy);  
            color += w1/sum * SAMPLE_TEXTURE2D_X(_MainTex, sampler_MainTex,IN.uv01.zw);  
            color += w2/sum * SAMPLE_TEXTURE2D_X(_MainTex, sampler_MainTex,IN.uv23.xy);  
            color += w2/sum * SAMPLE_TEXTURE2D_X(_MainTex, sampler_MainTex,IN.uv23.zw);

        	return color;
        }
        
        
        ENDHLSL
        
        
        Pass
        {
            HLSLPROGRAM

            #pragma vertex Vert
			#pragma fragment Frag
            
            Varyings Vert(Attributes IN)
            {
                Varyings OUT;
                OUT.position_sv = TransformObjectToHClip(IN.position);
                OUT.uv = TRANSFORM_TEX(IN.uv,_MainTex);


        		// 方案3使用
        		half4 _offsets = half4(3,0,0,0);
                _offsets *= _MainTex_TexelSize.xyxy;  
                OUT.uv01 = IN.uv.xyxy + _offsets.xyxy * float4(1, 1, -1, -1);  
                OUT.uv23 = IN.uv.xyxy + _offsets.xyxy * float4(1, 1, -1, -1) * 2.0;  
        	
                return OUT;
            }



            half4 Frag(Varyings IN) : SV_Target
            {
                return GaussBlur3(IN);
            }
            
            
            ENDHLSL
        }
        

    }




}